フローで考える音振動のモデリング（その2） 〜振動問題、音振動連成問題に適用する〜：1Dモデリングの勘所（35）（3/3 ページ）

[大富浩一／日本機械学会 設計研究会，MONOist]

音振動連成問題：解析例

　前節の式を用いて、Modelicaでテキスト表記すると以下のようになる（リスト2）。ここでは、部屋はいずれも1m立方、板は1m四方、板の内部損失係数は0.002、板厚は0.002m、周波数は1000Hzとした。また、参考文献［2］に従って、結合損失係数（透過率および放射率含む）の計算式もリスト2内に表記している。そのため、プログラム行数が多くなっている。

model energyAcousticPlateAcoustic
 import Modelica.Constants.pi;
 Real C1 “internal loss factor of acoustic field 1”;
 Real C2 “internal loss factor of plate”;
 Real C3 “internal loss factor of acoustic field 3”;
 Real E1 “energy of acoustic field 1”;
 Real E2 “energy of plate”;
 Real E3 “energy of acoustic field 3”;
 Real omg “target angular frequency”;
 Real ita1 “internal loss factor of acoustic field 1”;
 Real ita3 “internal loss factor of acoustic field 3”;
 Real ita12 “coupling loss factor from field1 to plate”;
 Real ita21 “coupling loss factor from plate to field1”;
 Real ita23 “coupling loss factor from plate to field3”;
 Real ita32 “coupling loss factor from field3 to plate”;
 Real ita13 “coupling loss factor from field 1 to 3” ;
 Real ita31 “coupling loss factor from field 3 to 1”;
 Real tau “transmission coefficient”;
 Real x “parameter of transmission coefficient” ;
 Real Z “acoustic impedance”;
 Real sig “emissivity” ;
 Real sig1 “part 1 of emissivity”;
 Real sig2 “part 2 of emissivity”;
 Real M  “mass”;
 Real N1 “mode numbers of field 1” ;
 Real N2 “mode numbers of plate”;
 Real N3 “mode numbers of field 3” ;
 Real k “function of plate thickness”;
 Real ga11 “sub-part of emissivity”;
 Real ga “critical frequency ratio”;
 Real beta “sub-part of emissivity”;
 Real ramc “sub-part of emissivity”;
 Real omgc “critical angular frequency”;
 Real freqc “critical frequency by Hz”;
 Real CC1 “part of elastic wave speed”;
 Real CC2 “elastic wave speed”;
 Real Alf “function of frequency”;
 Real Pd1 “internal loss power at field 1”;
 Real Pd2 “internal loss power at plate”;
 Real Pd3 “internal loss power at field 3”;
 Real P12 “power from field 1 to plate”;
 Real P23 “power pate to field 3”;
 Real P13 “power from field 1 to 3”;
 parameter Real P1=1 “input power to field 1”;
 parameter Real P2=0 “input power to plkate”;
 parameter Real P3=0 “input power to field 3”;
 parameter Real ita2=0.002 “internal loss coefficient of plate”;
 parameter Real C=340 “sound speed”;
 parameter Real S=1 “coupling area”;
 parameter Real V=1 “volume of field”;
 parameter Real A=1 “ area of plate”;
 parameter Real L=4  “perimeter of plate”;
 parameter Real freq=1000 “target frequency by Hz”;
 parameter Real ro=1.293 “density of air”;
 parameter Real rom=7830 “density of plate”;
 parameter Real h=0.002 “thickness of plate”;
 parameter Real nyu=0.28 “Poisson’s ratio of plate”;
 parameter Real E=2.1e11 “Young’s moduls of plate”;
equation
 P1=Pd1+P13+P12;
 P2=Pd2-P12+P23;
 P3=Pd3-P13-P23;
 C1=omg*ita1;
 C2=omg*ita2;
 C3=omg*ita3;
 ita1=C*S*Alf/(4*V*omg);
 ita3=C*S*Alf/(4*V*omg);
 omg=2*pi*freq;
 Alf=1.8e-4*freq^0.5;
 Pd1=C1*E1;
 Pd2=C2*E2;
 Pd3=C3*E3;
 P12=omg*(ita12*E1-ita21*E2);
 P23=omg*(ita23*E2-ita32*E3);
 P13=omg*(ita13*E1-ita31*E3);
 ita13=C*S*tau/(4*omg*V);
 ita31=C*S*tau/(4*omg*V);
 ita21=Z*S*sig/(omg*M);
 ita23=Z*S*sig/(omg*M);
 ita12=ita21*(N2/N1);
 ita32=ita23*(N2/N3);
 N2=S*omg/(4*pi*CC2*k);
 N1=V*omg^3/(6*pi^2*C^3);
 N3=V*omg^3/(6*pi^2*C^3);
 k=h/12^0.5;
 CC2=CC1/(1-nyu^2)^0.5;
 CC1=(E/rom)^0.5;
 Z=ro*C;
 tau=log(1+x^2)/(1+x^2);
 x=omg*M/(2*Z*S);
 M=rom*h*A;
 sig=sig1+sig2;
 sig1=(2*ga11*ga^2)*(ga/ga11)^0.25/((ga^2-ga11^2)^2+ga11^4)^0.5;
 sig2=ga^3.5*(ga^3.5+beta)/((ga^3.5-1)^2+beta);
 ga11=((L^2/(8*S))-1)*(ramc^2/(2*S));
 ramc=2*pi*C/omgc;
 omgc=C^2*(12*(1-nyu^2)*rom/(E*h^2))^0.5;
 freqc=omgc/(2*pi);
 beta=1/(0.5*L+(2/S^0.5)*(1/ramc))^0.5;
 ga=omg/omgc;
end energyAcousticPlateAcoustic;

リスト2　Modelicaでテキスト表現した場合

　解析結果は図5左図の通りだ。併せて、透過損失（式5）も示す。

図5　解析例［クリックで拡大］

式5

　図5左図と同じ条件で、対象周波数を5907Hzとしたときの結果を図5右図に示す。これから、音場1から音場3への音の透過損失が大きくなっていることが分かる。これは、入力の周波数が板のコインシデンス周波数（式6）に一致したためである。

式6

音振動連成問題：設計応用

　この場合も設計応用はさまざま考えられる。一例として、現設計が、図5右図の条件（入力周波数が5907Hz）になっていると考える。入力周波数は変更できないものとすると、コインシデンス周波数を変更すればよいと考えることができる。そこで、板厚を現状の0.002mから薄くした場合（0.001m）と厚くした場合（0.003m）について解析すると図6となる。

図6　板の厚さを変えた場合の結果［クリックで拡大］

　図6左図が板厚0.001m、図6右図が板厚0.003mの場合である。ここから、このケースでは「板を薄くした方がよい」ことが分かる。

　前回と今回とで、“フローで考える音振動のモデリング”について説明した。従来の「MCKモデル」による振動モデリングとは異なり、なじみの少ない方法ではあるが、いったん定式化を理解してしまえば、解析は連立方程式を解くだけなので計算負荷も小さい。また、音振動連成問題が解けること、高周波数域まで解析可能なことなど、メリットも大きい。入力を従来のMCKモデルで求め、これを用いて、本手法で振動パワーの動きを観察するといった適用方法も考えられる。

　次回から、数回にわたって、機構制御系のモデリングについて考える。　（次回へ続く）

⇒連載バックナンバーはこちら

筆者プロフィール：

大富浩一（https://1dcae.jp/profile/）

日本機械学会 設計研究会
本研究会では、“ものづくりをもっと良いものへ”を目指して、種々の活動を行っている。1Dモデリングはその活動の一つである。

• 最新著書：1Dモデリングの方法と事例（日本機械学会）
• 研究会HP：https://1dcae.jp/
• 代表者アドレス：[e-mail]