快適性をデザインする 〜快適性を保つエアコンの運転法〜：1Dモデリングの勘所（27）（3/4 ページ）

[大富浩一／日本機械学会 設計研究会，MONOist]

考えた運転法の検証

　前項で考えた快適性を保つエアコンの運転法を「Modelica」でテキスト表記すると以下となる（リスト1）。ここに、部屋の容積は72m²として部屋の熱容量を計算し、外壁の熱コンダクタンスは外壁の面積を12m²、厚さを0.1m、熱伝導率を11.5W/m・Kとして計算した。

model humanComfortAirconControl
    //Parameters
    parameter Real t0 = 15.0 "initial temperature C";
    parameter Real v = 0.2 "relative air flow m/s";
    parameter Real RH = 50 "relative humidity";
    parameter Real Wme = 0 "external work 58.15W/m2";
    parameter Real A = 1.7 "surface area of human m2";
    parameter Real V = 10e-6 "compressor volume m3";
    parameter Real dh = 1e5 "enthalpy difference J/kg";
    parameter Real ga = 1 / 75.31 "specific volume m3/kg";
    parameter Real Vr = 72 "room volume m3";
    parameter Real c = 1000 "specific heat of air J/kg/K";
    parameter Real ro = 1.2 "density of air kg/m3";
    parameter Real TF = 1 / 50 "transfer function from aircon to human";
    parameter Real tout = 10 "outside temperature C";
    parameter Real Aw = 12 "area of wall m2";
    parameter Real Hw = 0.1 "thickness of wall m";
    parameter Real ram = 1.5 "thermal condauctivity W/mK";
    //Variables
    Real Clo "thermal isolation of the cloths 0.155m2K/W";
    Real Met "metabolic rate 58.15W/m";
    Real temp(start = t0) "temperature C";
    Real ta "ambient temperature C";
    Real tr "mean radiant temperature C";
    Real Ta "ambient temperature K";
    Real Tr "mean radiant temperature K";
    Real Icl "thermal resistance of the cloths m2K/W";
    Real M "metabolic rate in Q/m2";
    Real W "external work in W/m2";
    Real hc "convective heat transfer coefficient W/m2K";
    Real fcl "ratio of clothed body";
    Real HL1 "heat loss for skin";
    Real HL2 "heat loss factor for sweat";
    Real HL3 "heat loss factor for latent respiration";
    Real HL4 "heat loss factor for dry respiration";
    Real HL5 "heat loss factor for radiation";
    Real HL6 "heat loss factor for convection";
    Real TS "thermal sensation transformation coefficient";
    Real Tcl "clothing surface temperature K";
    Real tcl "clothing surface temperature C";
    Real PMV "predicted mean value";
    Real PPD "predicted percentage of dissatisfied %";
    Real pa "water vapor pressure Pa";
    Real Q "stored power in human W";
    Real q "stored power per unit area W/m2";
    Real Qaircon "input power by airconditioner W";
    Real f "compressor frequency 1/s";
    Real Qroom "power to room W";
    Real Qout "power to outside W";
    Real G "thermal conductance W/K";
  equation
    ta = temp;
    tr = temp;
    Ta = 273 + ta;
    Tr = 273 + tr;
    if time < 600 then
      Met = 0.8;
    else
      Met = 1.2;
    end if;
    if time < 1800 then
      Clo = 0.5;
    else
      Clo = 1.0;
    end if;
    Icl = 0.155 * Clo;
    M = 58.15 * Met;
    W = 58.15 * Wme;
    Tcl = 273 + tcl;
    if Icl > 0.078 then
      fcl = 1.05 + 0.645 * Icl;
    else
      fcl = 1 + 1.29 * Icl;
    end if;
    if 2.38 * abs(Tcl - Ta) ^ 0.25 > 12.1 * sqrt(v) then
      hc = 2.38 * abs(Tcl - Ta) ^ 0.25;
    else
      hc = 12.1 * sqrt(v);
    end if;
    Tcl = 273 + 35.7 - 0.028 * (M - W) - Icl * (3.96e-8 * fcl * (Tcl ^ 4 - Tr ^ 4) + fcl * hc * (Tcl - Tr));
    pa = RH * 10 * exp(16.6536 - 4030.183 / (ta + 235));
    TS = 0.303 * exp(-0.036 * M) + 0.028;
    HL1 = 3.05 * 0.001 * (5733 - 6.99 * (M - W) - pa);
    if M - W > 58.15 then
      HL2 = 0.42 * (M - W - 58.15);
    else
      HL2 = 0;
    end if;
    HL3 = 1.7e-5 * M * (5867 - pa);
    HL4 = 0.0014 * M * (34 - ta);
    HL5 = 3.96e-8 * fcl * (Tcl ^ 4 - Tr ^ 4);
    HL6 = fcl * hc * (tcl - ta);
    PMV = TS * (M - W - HL1 - HL2 - HL3 - HL4 - HL5 - HL6);
    PPD = 100 - 95 * exp((-0.03353 * PMV ^ 4) - 0.2179 * PMV ^ 2);
    q = M - W - HL1 - HL2 - HL3 - HL4 - HL5 - HL6;
    Q = A * q;
    Q + Qroom * TF = 0;
    Qaircon = dh * V * f / ga;
    Qaircon = Qroom + Qout;
    der(temp) = Qroom / (ro * c * Vr);
    Qout = G * (temp - tout);
    G = ram * Aw / Hw;
  end humanComfortAirconControl;

リスト1　Modelicaでテキスト表現した場合