ひとが感じる快適さをモデリングする 〜ひとを熱的視点で捉える〜：1Dモデリングの勘所（26）（3/4 ページ）

[大富浩一／日本機械学会 設計研究会，MONOist]

快適性の評価

　快適性の評価は以下の式を用いて行う。

快適性に関する式：

熱的要因：

個人的要因：

PMV関数内の値:

衣服関連機能の定義：

対流伝達係数の定義：

［クリックで拡大］

蒸気圧p_aと相対湿度RHの関係：

全熱損失と温冷感変換係数の計算：

快適指標の計算：

不快割合の定義：

参考文献：

• ［3］B. Michaelsen and J. Eiden｜HumanComfort Modelica-Library Thermal Comfort in Buildings and Mobile Applications｜7th Modelica Conference, Como, Italy（2009）

快適性の解析

　前項の快適性の評価式を「Modelica」でテキスト表現すると以下となる。

model humanComfort
//Parameters
 parameter Real ta=25.0 "ambient temperature C";
 parameter Real tr=25.0 "mean radiant temperature C";
 parameter Real v=1.2 "relative air flow m/s";
 parameter Real RH=50 "relative humidity";
 parameter Real Clo=1.2 "thermal isolation of the cloths 0.155m2K/W";
 parameter Real Met=1.0 "metabolic rate 58.15W/m2";
 parameter Real Wme=0 "external work 58.15W/m2";
//Variables
 Real Ta "ambient temperature K";
 Real Tr "mean radiant temperature K";
 Real Icl "thermal resistance of the cloths m2K/W";
 Real M "metabolic rate in Q/m2";
 Real W "external work in W/m2";
 Real hc "convective heat transfer coefficient W/m2K";
 Real fcl "ratio of clothed body";
 Real HL1 "heat loss for skin";
 Real HL2 "heat loss factor for sweat";
 Real HL3 "heat loss factor for latent respiration";
 Real HL4 "heat loss factor for dry respiration";
 Real HL5 "heat loss factor for radiation";
 Real HL6 "heat loss factor for convection";
 Real TS "thermal sensation transformation coefficient";
 Real Tcl "clothing surface temperature K";
 Real tcl "clothing surface temperature C";
 Real PMV "predicted mean value";
 Real PPD "predicted percentage of dissatisfied %";
 Real pa "water vapor pressure Pa";
//Equations
equation
 Ta=273+ta;
 Tr=273+tr;
 Icl=0.155*Clo;
 M=58.15*Met;
 W=58.15*Wme;
 Tcl=273+tcl;
 if Icl>0.078 then
  fcl=1.05+0.645*Icl;
  else
  fcl=1+1.29*Icl;
 end if;
 if 2.38*(abs(Tcl-Ta))^0.25>12.1*sqrt(v) then
  hc=2.38*(abs(Tcl-Ta))^0.25;
  else
  hc=12.1*sqrt(v);
 end if;
 Tcl=273+35.7-0.028*(M-W)-Icl*(3.96e-8*fcl*(Tcl^4-Tr^4)+fcl*hc*(Tcl-Tr));
 pa=RH*10*exp(16.6536-4030.183/(ta+235));
 TS=0.303*exp(-0.036*M)+0.028;
 HL1=3.05*0.001*(5733-6.99*(M-W)-pa);
 if M-W>58.15 then
  HL2=0.42*(M-W-58.15);
  else
  HL2=0;
 end if;
 HL3=1.7e-5*M*(5867-pa);
 HL4=0.0014*M*(34-ta);
 HL5=3.96e-8*fcl*(Tcl^4-Tr^4);
 HL6=fcl*hc*(tcl-ta);
 PMV=TS*(M-W-HL1-HL2-HL3-HL4-HL5-HL6);
 PPD=100-95*exp(-0.03353*PMV^4-0.2179*PMV^2);
end humanComfort;

リスト1　Modelicaでテキスト表現した場合