フローで考える熱のモデリング（その3） 〜ドライヤーを例に熱のモデリングを行う〜：1Dモデリングの勘所（33）（4/4 ページ）

「1Dモデリング」に関する連載。連載第33回では「フローで考える熱のモデリング（その3）」と題し、ドライヤーを例に熱のモデリングを行う。

[大富浩一／日本機械学会 設計研究会，MONOist]

解析

　前項の式およびパラメータを、Modelicaでテキスト表現すると以下となる（リスト1）。

model dryerThermal
  import Modelica.Constants.pi;
  //heat circuit//
  Real T1(start = 20);
  Real T2(start = 20);
  Real T3(start = 20);
  Real Q1;
  Real Q2;
  Real Q1c;
  Real Q3c;
  Real Q3;
  Real Qin;
  Real C1;
  parameter Real G3 = 0.628;
  parameter Real H = 20;
  parameter Real C3 = 110;
  parameter Real Tr = 20;
 //electrical circuit to Qin//
  Real R "electrical resistance of heater";
  parameter Real E = 100 "voltage";
  parameter Real roe = 1.079e-6 "electrical registance coefficient";
  //heat capacity of heater C1//
  parameter Real roh = 8.4e3 "dencity of heater";
  parameter Real Ch = 450 "heat capacity coefficient";
//heat transfer coefficient of convection G1//
  Real v "wind velocity"; 
  Real a "duct area";
  Real Pr;
  Real Re;
  Real G1 "heat conductance";
  Real h "heat transfer ratio";
  Real mu;
  Real A "heat transfer area of heater";
  parameter Real ram = 0.03;
  parameter Real c = 1000;
  parameter Real nu = 15e-6;
  parameter Real q = 0.02;
  parameter Real phid = 0.04 "diameter of duct";
  parameter Real phih = 1e-3 "diameter of heater";
  parameter Real Lh = 8 "length of heater";
  parameter Real ro = 1.293;
  //radiation G2//
  Real G2;
  Real Ah;
  parameter Real sig=5.67e-8;
  parameter Real eps=0.95;
equation
  //Qin//
  Qin = E^2/R ;
  R = roe*Lh/((pi/4)*(phih^2));
  //C1//
  C1 = roh*Lh*((pi/4)*phih^2)*Ch;
  //G1//
  Pr = mu*c/ram;
  Re = v*phih/nu;
  h*phih/ram = 1.14*Pr^0.4*Re^(1/2);
  A=0.5*pi*phih*Lh;
  G1 = h*A;
  v = q/a;
  a = (pi/4)*phid^2;
  mu = ro*nu;
//G2//
  Ah=pi*phih*Lh;
  G2=Ah*eps*sig;
  //heat circuit//
  Qin = Q1c + Q1 + Q2;
  Q2 = Q3c + Q3;
  Q1 = G1*(T1 - T2);
  Q2 = G2*((T1 + 273)^4 - (T3 + 273)^4);
  Q3 = G3*(T3 - Tr);
  der(T1) = Q1c/C1;
  T2 - Tr = Q1/H;
  der(T3) = Q3c/C3;
end dryerThermal;

リスト1　Modelicaでテキスト表現した場合

　また、MSLで表現すると図7となる。テキスト表現では、熱コンダクタンス、熱容量の計算もプログラム内で実施しているが、MSLを使用した場合はいったん外部で計算して入力することになる。

図7　Modelica標準ライブラリ（MSL）モデル［クリックで拡大］

結果の評価

　図8に解析例を示す。当然のことながら、テキストでもMSLでも同じ結果となる。起動して10秒間の結果を示しているが、最初熱はヒーターを熱くするのに使用され（Q1c）、この結果、ヒーター温度（T1）が上昇し、次にヒーターと流れとの間の熱交換が行われ（Q1）、流れの温度（T2）が上昇する。放射伝熱によって筐体に伝わった熱（Q2）はさらに、筐体を熱伝導で温め、温度（T3）が若干上昇する。

図8　解析例［クリックで拡大］

　図8からは、各部の温度、熱量の時間変化を知ることにより、現象の理解が進む。一方、この種の非定常問題は立ち上がりの現象を把握するにはよいが、最終的に温度がどうなるのかを知るには解が収束するまで解析する必要がある。そこで問題を定常問題に置き換える。すなわち、

式25

を

式26

として解析すると、収束値

式27

が得られる。

　一方、パラメータで不確定性が大きいのは強制対流熱伝達率である。実際に実験で強制対流熱伝達率を求めるのは容易ではない。しかしながら、温度を測定することは比較的容易である。そこで、例えば、ヒーター温度を計測して、強制対流熱伝達率を解析により求める（推定する）ことを考える。これを一般に「逆解析」という。具体的には、前述のプログラム式で、T1を変数からパラメータに、G1をパラメータから変数にすればよい。解析例を以下に示す。

• T1＝139.7℃の時、G1＝11.76［W/K］←前述の結果を逆解析で求めたもの（当然結果は一致する）
• T1＝100℃の時、G1＝25.51［W/K］
• T1＝200℃の時、G1＝6.33［W/K］

となり、熱伝達が良くなるとヒーター温度は低くなるという経験的事実と一致する。なお、前述の定常問題、この逆解析はMSLでは困難である。テキスト計算の特徴である。

---

　次回は、フローで考える音振動のモデリングについて紹介する。　（次回へ続く）

⇒連載バックナンバーはこちら

筆者プロフィール：

大富浩一（https://1dcae.jp/profile/）

日本機械学会 設計研究会
本研究会では、“ものづくりをもっと良いものへ”を目指して、種々の活動を行っている。1Dモデリングはその活動の一つである。

• 最新著書：1Dモデリングの方法と事例（日本機械学会）
• 研究会HP：https://1dcae.jp/
• 代表者アドレス：[e-mail]